pkgname=xinetd
pkgver=2.3.14
pkgrel=1
pkgdesc="xinetd is a secure replacement for inetd"
arch=('i686' 'x86_64')
url="http://www.xinetd.org/"
license=('custom')
depends=('tcp_wrappers')
optdepends=('perl: for xconv.pl script')
backup=('etc/xinetd.conf' 'etc/xinetd.d/servers' 'etc/xinetd.d/services')
source=("http://www.xinetd.org/xinetd-$pkgver.tar.gz"
        'xinetd.conf'
        'rc.xinetd'
        'servers'
        'services')
md5sums=('567382d7972613090215c6c54f9b82d9'
         'f109f699a07bc8cfb5791060f5e87f9e'
         'ea37a2794f202e6b953d9b6956dad16a'
         '21f47b4aa20921cfaddddd9f9a407f81'
         '9fa2061dc7dd738c8424251deb86f81e')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  sed -i "s#${prefix}/man#${prefix}/share/man#" configure || return 1
  ./configure --prefix=/usr --with-libwrap || return 1
  make || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make prefix=$pkgdir/usr install || return 1
  install -D -m755 $srcdir/rc.xinetd $pkgdir/etc/rc.d/xinetd || return 1
  install -D -m644 $srcdir/xinetd.conf $pkgdir/etc/xinetd.conf || return 1
  install -D -m644 $srcdir/servers $pkgdir/etc/xinetd.d/servers || return 1
  install -D -m644 $srcdir/services $pkgdir/etc/xinetd.d/services || return 1

  # install license
  install -D -m644 COPYRIGHT $pkgdir/usr/share/licenses/$pkgname/COPYRIGHT || return 1
}

# vim:set ts=2 sw=2 et:
