# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>

pkgname=rsyslog
pkgver=5.6.4
pkgrel=4
pkgdesc="An enhanced multi-threaded syslogd with a focus on security and reliability"
url="http://www.rsyslog.com/"
arch=('i686' 'x86_64')
license=('GPL3')
groups=('base')
depends=('zlib')
makedepends=('postgresql-libs>=8.4.1' 'libmysqlclient' 'net-snmp')
optdepends=('postgresql-libs: PostgreSQL Database Support'
            'libmysqlclient: MySQL Database Support'
            'net-snmp'
            'logrotate')
backup=('etc/rsyslog.conf' \
	'etc/logrotate.d/rsyslog')
source=("http://download.rsyslog.com/$pkgname/$pkgname-$pkgver.tar.gz" \
        "rc.$pkgname" \
        "$pkgname.logrotate")
md5sums=('0530db8ca71575ef23a027e9d514aa7e'
         '136d3ec0c7b46979f8750ae4c45b3ed5'
         '3cb32c7353e4b3d4837617abe80d9241')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  ./configure \
    --prefix=/usr \
    --enable-mysql \
    --enable-pgsql \
    --enable-mail \
    --enable-imfile \
    --enable-imtemplate \
    --enable-snmp \
    --enable-inet
  
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  # install base program
  make DESTDIR=${pkgdir} install

  # install rc init script
  install -Dm755 $srcdir/rc.$pkgname $pkgdir/etc/rc.d/${pkgname}d
  
  # install config file
  install -Dm644 $pkgname.conf $pkgdir/etc/$pkgname.conf

  # fix log filenames to be like 'normal' Arch style
  #    /var/log/messages => /var/log/messages.log
  sed -e 's|/var/log/\([^.]*$\)|/var/log/\1.log|g' \
      -i $pkgdir/etc/rsyslog.conf
  sed -e 's|/var/log/maillog.log|/var/log/mail.log|g' \
      -e 's|/var/log/secure.log|/var/log/auth.log|g' \
      -i $pkgdir/etc/rsyslog.conf
  
  # install logrotate script
  install -Dm644 $srcdir/$pkgname.logrotate $pkgdir/etc/logrotate.d/$pkgname
  
  # install licence
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}

# vim:set ts=2 sw=2 et:
