# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>

pkgname=rsyslog
pkgver=3.22.1
pkgrel=1
pkgdesc="An enhanced multi-threaded syslogd with a focus on security and reliability"
url="http://www.rsyslog.com/"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('zlib' 'net-snmp')
makedepends=('postgresql-libs>=8.4.1' 'libmysqlclient')
optdepends=('postgresql-libs: PostgreSQL Database Support'
            'libmysqlclient: MySQL Database Support')
backup=('etc/rsyslog.conf' \
	'etc/logrotate.d/rsyslog')
source=("http://download.rsyslog.com/$pkgname/$pkgname-$pkgver.tar.gz" \
        "rc.$pkgname" \
        "$pkgname.logrotate")
md5sums=('64bed3d5535c17d631f7432a5badf959'
         '136d3ec0c7b46979f8750ae4c45b3ed5'
         '8065db4bef3061a4f000ba58779f6829')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  ./configure \
    --prefix=/usr \
    --enable-mysql \
    --enable-pgsql \
    --enable-mail \
    --enable-imfile \
    --enable-imtemplate \
    --enable-snmp \
    --enable-inet || return 1
  
  make || return 1
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  # install base program
  make DESTDIR=${pkgdir} install || return 1
  
  # install rc init script
  install -Dm755 $srcdir/rc.$pkgname $pkgdir/etc/rc.d/${pkgname}d || return 1
  
  # install config file
  install -Dm644 $pkgname.conf $pkgdir/etc/$pkgname.conf || return 1
  
  # install logrotate script
  install -Dm644 $srcdir/$pkgname.logrotate $pkgdir/etc/logrotate.d/$pkgname || return 1
  
  # install licence
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING || return 1
}

# vim:set ts=2 sw=2 et:
