# Maintainer: Markus M. May <triplem@tu.archserver.org>

pkgname=openssl
pkgver=0.9.8r
pkgrel=1
pkgdesc='The Open Source toolkit for Secure Sockets Layer and Transport Layer Security'
arch=('i686' 'x86_64')
url='http://www.openssl.org'
license=('custom:BSD')
depends=('zlib' 'perl')
optdepends=('ca-certificates')
options=('!makeflags')
backup=('etc/ssl/openssl.cnf')
# other patches from http://cvs.fedoraproject.org/viewvc/rpms/openssl/devel/
source=("http://www.openssl.org/source/${pkgname}-${pkgver}.tar.gz"
        'openssl-0.9.8a-no-rpath.patch')
md5sums=('0352932ea863bc02b056cda7c9ac5b79'
         '4738d1eaff4e9975e9a26e4f76e48318')

build() {
	cd $srcdir/$pkgname-$pkgver
  
	# remove rpath: http://bugs.archlinux.org/task/14367
	patch -p1 -i $srcdir/openssl-0.9.8a-no-rpath.patch
	
  # mark stack as non-executable: http://bugs.archlinux.org/task/12434
	./config --prefix=/usr --openssldir=/etc/ssl shared zlib -Wa,--noexecstack
  
	make || return 1
}

package() {
	cd $srcdir/$pkgname-$pkgver
  
	make INSTALL_PREFIX=$pkgdir MANDIR=/usr/share/man install

	# the test fails due to missing write permissions in /etc/ssl
	# revert this patch for make test
	# patch -p1 -R -i $srcdir/openssl-0.9.8j-ca-dir.patch
	# make test || return 1

	install -D -m644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et:
