# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Mark Rosenstand <mark@borkware.net>
# Contributor: Giorgio Lando <patroclo7@gmail.com> (adjtimex patch)

pkgname=openntpd
pkgver=3.9p1
pkgrel=1
pkgdesc="Free, easy to use implementation of the Network Time Protocol."
url="http://www.openntpd.org/"
arch=('i686' 'x86_64')
license=(BSD)
depends=('openssl')
backup=('etc/ntpd.conf')
install='openntpd.install'
source=("ftp://ftp.openbsd.org/pub/OpenBSD/OpenNTPD/$pkgname-$pkgver.tar.gz"
        "rc.$pkgname"
        "confd.$pkgname"
        'linux-adjtimex.patch'
        'ntpd.conf')
md5sums=('afc34175f38d08867c1403d9008600b3'
         '83e3cc4914f14758773982c7425cd378'
         'ab38a035cbebe7a52888db6c573944a5'
         '6e04eecf89ee794d6f1ae79f03742cf9'
         'b0c960644adc50d9914209fb489b3512')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  patch -Np1 -i ../linux-adjtimex.patch 

  autoconf

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --with-privsep-user=ntp \
    --with-privsep-path=/var/empty \
    --with-adjtimex || return 1

  make || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make DESTDIR=$pkgdir install || return 1
  
  # install rc init script
  install -Dm755 $srcdir/rc.$pkgname $pkgdir/etc/rc.d/$pkgname || return 1
  
  # install rc init script config file
  install -Dm644 $srcdir/confd.$pkgname $pkgdir/etc/conf.d/$pkgname || return 1
  
  # install defaul confgi file
  rm -f $pkgdir/etc/ntpd.conf
  install -Dm644 $srcdir/ntpd.conf $pkgdir/etc/ntpd.cond || return 1
  
  # install licence
  install -Dm644 $srcdir/$pkgname-$pkgver/LICENCE  $pkgdir/usr/share/licenses/$pkgname/LICENCE || return 1

  # Remove /var/empty as per: http://bugs.archlinux.org/task/16886
  rmdir $pkgdir/var/empty || return 1
}

# vim:set ts=2 sw=2 et:
