# Maintainer: judd <jvinet@zeroflux.org>

pkgname=net-tools
pkgver=1.60
pkgrel=2
pkgdesc="Configuration tools for Linux networking"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.tazenda.demon.co.uk/phil/net-tools"
groups=('base')
depends=('glibc')
backup=('etc/conf.d/nisdomainname')
options=(!makeflags)
source=("http://www.tazenda.demon.co.uk/phil/$pkgname/$pkgname-$pkgver.tar.bz2"
        "net-tools.patch"
        "gcc340.patch"
        "net-tools-1.60-2.6-compilefix.patch"
        "net-tools-1.60-miiioctl.patch"
        "nisdomainname.conf.d"
        "net-tools-1.60-nameif.patch"
        "net-tools-1.60-nameif_strncpy.patch")
md5sums=('888774accab40217dde927e21979c165' 
      	 '7ef8d0c6818faa0fdeea94970a20e3fb'
         'b52d899cba9956bb0055150506f41ac1' 
      	 '51de6eabe2d6d6dc860f72c41cee636b'
         'c16109863bc63f3dad4ef35305a340bb' 
      	 'af3eef5d4837939f7858eec692aa4671'
         '29a32617382fab1735acba4d920f1fcd' 
      	 'e66466b9304dac85eb42b32f1ec3b284')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  patch -Np1 -i $srcdir/net-tools.patch || return 1
  patch -Np1 -i $srcdir/net-tools-1.60-2.6-compilefix.patch || return 1
  patch -Np1 -i $srcdir/net-tools-1.60-miiioctl.patch || return 1
  patch -Np1 -i $srcdir/gcc340.patch || return 1
  patch -Np1 -i $srcdir/net-tools-1.60-nameif.patch || return 1
  patch -Np1 -i $srcdir/net-tools-1.60-nameif_strncpy.patch || return 1
  
  yes "" | make || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make BASEDIR=$pkgdir update || return 1
  
  install -Dm644 $srcdir/nisdomainname.conf.d $pkgdir/etc/conf.d/nisdomainname || return 1
}

# vim:set ts=2 sw=2 et:
