# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: lydgate

pkgname=mlocate
pkgver=0.23.1
pkgrel=1
pkgdesc="Faster merging drop-in for slocate"
arch=('i686' 'x86_64')
url="http://carolina.mff.cuni.cz/~trmac/blog/mlocate"
license=('GPL')
groups=('base')
conflicts=('slocate')
provides=('slocate')
replaces=('slocate')
depends=('glibc' 'sh')
backup=('etc/updatedb.conf'
        'etc/cron.daily/updatedb')
install="$pkgname.install"
source=("https://fedorahosted.org/releases/m/l/mlocate/mlocate-$pkgver.tar.xz"
	'updatedb.conf'
	'updatedb.cron.daily')
md5sums=('db48f27fae91c754c46d8046919803c5'
         '66898efb290eff4efd44a0b94fe3927d'
         'cde5da81bebad2de556ef2e43d895e13')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  # Build!
  sed \
    -e '/^groupname /s/mlocate/locate/' \
    -i Makefile.in || return 1
  
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var/lib || return 1
  
  make || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  # Set up a default updatedb.conf and a daily cronjob
  install -Dm644 $srcdir/updatedb.conf $pkgdir/etc/updatedb.conf || return 1
  install -Dm744 $srcdir/updatedb.cron.daily $pkgdir/etc/cron.daily/updatedb || return 1
  
  # Install Mlocate
  make DESTDIR=$pkgdir install || return 1
  
  ln -sv locate $pkgdir/usr/bin/slocate || return 1
  chgrp -v 21 $pkgdir/usr/bin/locate || return 1
  chmod -v 2755 $pkgdir/usr/bin/locate || return 1
  
  install -dm755 $pkgdir/var/lib || return 1
  install -d -m750 -g21 $pkgdir/var/lib/locate || return 1
}

# vim:set ts=2 sw=2 et:
