# Maintainer: Eric Belanger <eric@archlinux.org>

pkgname=('lvm2' 'device-mapper')
pkgver=2.02.84
_pkgverdm=1.02.38
_pkgverlvm=${pkgver}
pkgrel=2
arch=('i686' 'x86_64')
url="http://sourceware.org/lvm2/"
license=('GPL')
groups=('base')
source=("http://ftp.cs.pu.edu.tw/Linux/sourceware/lvm2/LVM2.${_pkgverlvm}.tgz"
        'lvm2_install'
        'lvm2_hook'
        'device-mapper.rules')
md5sums=('8b4e0897ee48f02c0dff11940e44e23b'
         '40dccdb1044f00fc1e29ca549933d4bd'
         'd6f3ca901747c386aa0d842e9ea64413'
         '065f32a36947e6183722ed9aef13dc0c')

build() {
  cd ${srcdir}/LVM2.${_pkgverlvm}
  
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --enable-readline \
    --enable-pkgconfig \
    --enable-static_link \
    --with-staticdir=/sbin || return 1
  
  make || return 1
}

package_device-mapper() {
  pkgdesc="Device mapper userspace library and tools"
  url="http://sourceware.org/dm/"
  depends=('glibc' 'readline')
  
  cd ${srcdir}/LVM2.${_pkgverlvm} || return 1
  
  make \
    DESTDIR=$pkgdir \
    sbindir=$pkgdir/sbin \
    libdir=$pkgdir/lib \
    install_device-mapper || return 1
  
  # install udev rule
  install -D -m644 $srcdir/device-mapper.rules $pkgdir/etc/udev/rules.d/device-mapper.rules || return 1
  
  # fix device-mapper link bug
  ln -sf /lib/libdevmapper.so $pkgdir/usr/lib/libdevmapper.so || return 1
}

package_lvm2() {
  pkgdesc="Logical Volume Manager 2 utilities"
  depends=('bash' "device-mapper>=${_pkgverdm}")
  conflicts=('lvm')
  backup=('etc/lvm/lvm.conf')
  options=('!makeflags')
  
  cd $srcdir/LVM2.${_pkgverlvm} || return 1
  
  make DESTDIR=$pkgdir sbindir=$pkgdir/sbin install_lvm2 || return 1
  
  install -d $pkgdir/etc/lvm/{archive,backup} || return 1
  
  # add hook
  install -D -m644 $srcdir/lvm2_hook $pkgdir/lib/initcpio/hooks/lvm2 || return 1
  install -D -m644 $srcdir/lvm2_install $pkgdir/lib/initcpio/install/lvm2 || return 1
}

# vim:set ts=2 sw=2 et:
