# Maintainer: judd <jvinet@zeroflux.org>
pkgname=groff
pkgver=1.20.1
pkgrel=2
pkgdesc="GNU troff text-formatting system"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/groff/groff.html"
license=('GPL')
groups=('base')
depends=('perl' 'gcc-libs' 'texinfo')
makedepends=('netpbm' 'psutils' 'ghostscript')
source=("ftp://ftp.gnu.org/gnu/groff/groff-$pkgver.tar.gz"
        'site.tmac')
install="groff.install"
md5sums=('48fa768dd6fdeb7968041dd5ae8e2b02'
         '7b47109b2dd1797445c912574d8934a1')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  ./configure \
    --prefix=/usr \
    --without-x || return 1
  
  mkdir -p $pkgdir/usr || return 1
  
  make -j1 || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make prefix=$pkgdir/usr install

	cd $pkgdir/usr/bin || return 1

	# needed for xman
	ln -s eqn geqn || return 1
	ln -s tbl gtbl || return 1
	ln -s soelim zsoelim || return 1
  rm -rf $pkgdir/usr/lib || return 1
  
  # Fix some issues when encoding to utf8 man pages
  # The output chars don't match keyboard chars...
  cat $srcdir/site.tmac >> $pkgdir/usr/share/groff/site-tmac/man.local
  cat $srcdir/site.tmac >> $pkgdir/usr/share/groff/site-tmac/mdoc.local
  
  rm -f $pkgdir/usr/share/info/dir || return 1
}

# vim:set ts=2 sw=2 et:
