# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=gpm
pkgver=1.20.6
pkgrel=1
pkgdesc="A mouse server for the console and xterm"
arch=('i686' 'x86_64')
url="http://unix.schottelius.org/gpm/"
license=('GPL')
depends=('ncurses' 'texinfo')
backup=('etc/conf.d/gpm')
options=('!makeflags')
install="$pkgname.install"
source=("http://www.nico.schottelius.org/software/$pkgname/archives/${pkgname}-${pkgver}.tar.bz2"
        "confd.$pkgname"
        "rc.$pkgname")
md5sums=('6b534da16dc1b28ba828dea89e520f6f'
         '63e599950946e5f5a649432510aacf4c'
         '945ecde0836687e05c13ea837092ea6c')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc || return 1
  
  make || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make DESTDIR=$pkgdir install || return 1
  install -Dm755 $srcdir/rc.$pkgname $pkgdir/etc/rc.d/$pkgname || return 1
  install -Dm644 $srcdir/confd.$pkgname $pkgdir/etc/conf.d/$pkgname || return 1
  
  # library fixes
  cd $pkgdir/usr/lib/
  ln -s libgpm.so.2.* libgpm.so || return 1
  chmod 755 $pkgdir/usr/lib/libgpm.so.* || return 1
}

# vim:set ts=2 sw=2 et:
