# $Id: PKGBUILD 6013 2009-11-25 10:47:47Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Jason R Begley (jayray@digitalgoat.com>

pkgname=freeradius
pkgver=2.1.8
pkgrel=1
pkgdesc="The premier open source RADIUS server."
arch=('i686' 'x86_64')
url="http://www.freeradius.org/"
license=("GPL")
depends=('openssl' 'heimdal' 'pth' 'libldap>=2.4.18' 'net-snmp' 'pam' \
	 'postgresql-libs>=8.4.1' 'libtool' 'libmysqlclient' 'gdbm' 'shadow')
optdepends=('unixodbc: for using rlm_sql_unixodbc'
            'python: for using rlm_python' 
            'libpcap: for using radsniff')
options=(!libtool emptydirs !makeflags)
install=$pkgname.install
source=(ftp://ftp.freeradius.org/pub/radius/freeradius-server-$pkgver.tar.gz \
        radiusd
        krb.patch)
md5sums=('aa2ae711387af144df7c351b28b8789c'
         '655d2d6764e0730d64e5d92e75794b51'
         'b3ee328919fff2eec11b134fc1a3d093')

build() {
  cd $startdir/src/freeradius-server-$pkgver

  export CFLAGS="$CFLAGS -fno-strict-aliasing"
  # patch for rlm_krb5, otherwise it wont build.
  patch -p0 -i $startdir/krb.patch || return 1

  ./configure --with-system-libtool \
	      --prefix=/usr --enable-heimdal-krb5 \
	      --localstatedir=/var \
	      --sysconfdir=/etc \
	      --libdir=/usr/lib/freeradius

  make || return 1
  make install R=$startdir/pkg || return 1

  install -D -m755 ../radiusd $startdir/pkg/etc/rc.d/radiusd && \
  chmod o+r $startdir/pkg/etc/raddb/*
  sed -i -e 's|#user = radius|user = radiusd|g' $pkgdir/etc/raddb/radiusd.conf
  sed -i -e 's|#group = radius|group = radiusd|g' $pkgdir/etc/raddb/radiusd.conf
  touch $pkgdir/var/log/radius/radius.log
  touch $pkgdir/var/run/radiusd/radiusd.pid
}
