# Maintainer: Andreas Radke <andyrtr@archlinux.org>

pkgbase="cups"
pkgname=('libcups' 'cups')
pkgver=1.4.1
pkgrel=1
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.cups.org/"
options=('!emptydirs')
makedepends=('libtiff>=3.9.1'
             'libpng>=1.2.39'
             'acl'
             'openslp'
             'pam'
             'xdg-utils'
             'heimdal>=1.2.1-5'
             'gnutls>=2.8.3'
             'poppler>=0.10.7-2'
             'xinetd'
             'gzip'
             'autoconf'
             'php'
             'libusb'
             'dbus-glib'
             'avahi'
             'hicolor-icon-theme') 
source=("ftp://ftp.easysw.com/pub/cups/${pkgver}/cups-${pkgver}-source.tar.bz2"
        'rc.cups'
        'cups.logrotate'
        'cups.pam')
md5sums=('587a58039c112ecb3c932e048c8a7b01'
         '5c85b7d8d2ddd02c2c64955cebbf55ea'
         'f861b18f4446c43918c8643dcbbd7f6d'
         '96f82c38f3f540b53f3e5144900acf17')

build() {
  cd ${srcdir}/${pkgbase}-${pkgver}

  # Rebuild configure script for --enable-avahi.
  aclocal -I config-scripts
  autoconf -I config-scripts

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --with-logdir=/var/log/cups \
    -with-docdir=/usr/share/cups/doc \
    --with-cups-user=daemon \
    --with-cups-group=lp \
    --enable-pam=yes \
    --disable-ldap \
    --libdir=/usr/lib \
    --enable-raw-printing \
    --enable-dbus \
    --with-dbusdir=/etc/dbus-1 \
    --enable-ssl=yes \
    --enable-gnutls \
    --with-php=/usr/bin/php-cgi \
    --with-pdftops=pdftops \
    --with-optim="$CFLAGS" || return 1

  make || return 1
}

package_libcups() {
  pkgdesc="The CUPS Printing System - client libraries and headers"
  depends=('gnutls>=2.8.3' 'libtiff>=3.9.1' 'libpng>=1.2.39' 'heimdal>=1.2.1-5')

  cd ${srcdir}/${pkgbase}-${pkgver}

  make BUILDROOT=${pkgdir} install-headers install-libs || return 1

  # put this into the libs pkg to make other software find the libs(no pkg-config file included)
  mkdir -p ${pkgdir}/usr/bin
  install -m755 ${srcdir}/${pkgbase}-${pkgver}/cups-config ${pkgdir}/usr/bin/cups-config
}

package_cups() {
  pkgdesc="The CUPS Printing System - deamon package"
  install=cups.install
  backup=(etc/cups/cupsd.conf
          etc/cups/mime.convs
          etc/cups/mime.types
          etc/cups/snmp.conf
          etc/dbus-1/system.d/cups.conf
          etc/logrotate.d/cups
          etc/pam.d/cups
          etc/xinetd.d/cups-lpd)
  depends=('acl' 'openslp' 'pam' "libcups>=${pkgver}" 'xdg-utils' 'heimdal>=1.2.1-5' 'gnutls>=2.8.3' 'poppler>=0.10.7-2' 
         'libusb' 'dbus-glib' 'avahi' 'hicolor-icon-theme')
  optdepends=('php: for included phpcups.so module')
  
  cd ${srcdir}/${pkgbase}-${pkgver}
  make BUILDROOT=${pkgdir} install-data install-exec || return 1
  
  # this one we ship in the libcups pkg
  rm -f ${pkgdir}/usr/bin/cups-config
  
  # kill the sysv stuff
  rm -rf ${pkgdir}/etc/rc*.d
  rm -rf ${pkgdir}/etc/init.d

  # install rc script
  install -Dm755 $srcdir/rc.cups ${pkgdir}/etc/rc.d/cups

  # install logrotate script
  install -Dm644 $srcdir/cups.logrotate ${pkgdir}/etc/logrotate.d/cups

  # install pam conf
  install -Dm644 $srcdir/cups.pam ${pkgdir}/etc/pam.d/cups
  
  # fix permissions
  chmod 755 ${pkgdir}/var/spool
  chmod 755 ${pkgdir}/etc
  
  # fix .desktop file
  sed \
    -e 's|^Exec=htmlview http://localhost:631/|Exec=xdg-open http://localhost:631/|g' \
    -i ${pkgdir}/usr/share/applications/cups.desktop
  
  # compress some driver files, adopted from Fedora
  find ${pkgdir}/usr/share/cups/model -name "*.ppd" | xargs gzip -n9f
}

# vim:set ts=2 sw=2 et:
