# Maintainer: Markus M. May <triplem@tu.archserver.org>
# Contributor: Judd <jvinet@zeroflux.org>

pkgname=bzip2
pkgver=1.0.6
pkgrel=1
pkgdesc="A high-quality data compression program"
arch=('i686' 'x86_64')
license=('custom')
url="http://sources.redhat.com/bzip2"
groups=('base')
depends=('glibc')
source=("http://www.bzip.org/$pkgver/bzip2-$pkgver.tar.gz")
md5sums=('00b516f4704d4a7cb50a1d97e6e8e15b')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  # add large-file support
  sed -e 's/^CFLAGS=\(.*\)$/CFLAGS=\1 \$(BIGFILES)/' -i ./Makefile-libbz2_so || return 1
  
  # use our optimization
  sed -i "s|-O2|${CFLAGS}|g" Makefile || return 1
  sed -i "s|-O2|${CFLAGS}|g" Makefile-libbz2_so || return 1
  
  make -f Makefile-libbz2_so || return 1
  make bzip2recover libbz2.a || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  install -dm755 $pkgdir/bin || return 1
  install -m755 bzip2-shared $pkgdir/bin/bzip2 || return 1
  install -m755 bzip2recover $pkgdir/bin || return 1
  ln -sf bzip2 $pkgdir/bin/bunzip2 || return 1
  ln -sf bzip2 $pkgdir/bin/bzcat || return 1
  
  install -Dm755 libbz2.so.$pkgver $pkgdir/lib/libbz2.so.$pkgver || return 1
  
  install -Dm755 libbz2.so.$pkgver $pkgdir/lib/libbz2.so.$pkgver || return 1
  ln -s libbz2.so.$pkgver $pkgdir/lib/libbz2.so || return 1
  ln -s libbz2.so.$pkgver $pkgdir/lib/libbz2.so.1 || return 1
  ln -s libbz2.so.$pkgver $pkgdir/lib/libbz2.so.1.0 || return 1
  
  install -Dm644 libbz2.a ${pkgdir}/usr/lib/libbz2.a || return 1
  ln -sf ../../lib/libbz2.so ${pkgdir}/usr/lib/libbz2.so || return 1
  
  install -Dm644 bzlib.h $pkgdir/usr/include/bzlib.h || return 1
  
  install -Dm644 bzip2.1 $pkgdir/usr/share/man/man1/bzip2.1 || return 1
  ln -sf bzip2.1 $pkgdir/usr/share/man/man1/bunzip2.1 || return 1
  ln -sf bzip2.1 $pkgdir/usr/share/man/man1/bzcat.1 || return 1
  ln -sf bzip2.1 $pkgdir/usr/share/man/man1/bzip2recover.1 || return 1
  
  install -Dm644 $srcdir/${pkgname}-${pkgver}/LICENSE $pkgdir/usr/share/licenses/${pkgname}/LICENSE || return 1
}

# vim:set ts=2 sw=2 et:
